R60
Listing 4.  Modified CONIN routine.  When particular
characters are typed at the keyboard, escape sequences are
sent to the screen.  In this particular example, typing a
tilde causes the escape sequence to select a blinking block
cursor to be sent to the screen, while typing a back
apostrophe sets the cursor to a blinking underline (for my
Televideo terminal). Thanks to Howard Goldstein for this
improvement to my original code.

     --------------------------------------------------

ICONIN:	LD	A,9		; Perform the BIOS call
	CALL	DOBIOS
	CP	'~'		; If tilde, send out
	JR	Z,SEQ1		; ..sequence 1
	CP	'`'		; If not back apostrophe,
	RET	NZ		; ..return to calling
				; .. program
; Back apostrophe was typed
	PUSH	AF		; Save input character
	LD	A,'3'
	JR	SEQ

SEQ1:	PUSH	AF		; Save input character
	LD	A,'1'

SEQ:	LD	(POKE+1),A	; Poke in final character
	PUSH	BC
	LD	C,1BH		; Send escape to screen
	CALL	ICONOT
	LD	C,'.'		; Send period to screen
	CALL	ICONOT
POKE:	LD	C,$-$		; Filled in from above
	CALL	ICONOT		; Send last char to screen
	POP	BC
	POP	AF		; Get input character back
	RET
                 